ucosII在stm32的疑问，困扰许久

li6915645

ucosII在stm32的疑问，困扰许久 [复制链接]

 任务切换是通过产生一个PendSV中断，在中断服务程序中实现的。进入中断时保存了近一半的寄存器的值。我的理解是应该把这些值保存到任务堆栈中，但下面的代码并没有体现出。我很困惑，这些寄存器的值究竟保存在什么地方，与任务的堆栈的是否有关系？困扰许久，跪求高人指点
   OS_CPU_PendSVHandler
    CPSID   I                                                   ; Prevent interruption during context switch
    MRS     R0, PSP                                             ; PSP is process stack pointer
    CBZ     R0, OS_CPU_PendSVHandler_nosave                     ; Skip register save the first time
 
    SUBS    R0, R0, #0x20                                       ; Save remaining regs r4-11 on process stack
    STM     R0, {R4-R11}
 
    LDR     R1, =OSTCBCur                                       ; OSTCBCur->OSTCBStkPtr = SP;
    LDR     R1, [R1]
    STR     R0, [R1]                                            ; R0 is SP of process being switched out
 
                                                                ; At this point, entire context of process has been saved
OS_CPU_PendSVHandler_nosave
    PUSH    {R14}                                               ; Save LR exc_return value
    LDR     R0, =OSTaskSwHook                                   ; OSTaskSwHook();
    BLX     R0
    POP     {R14}
 
    LDR     R0, =OSPrioCur                                      ; OSPrioCur = OSPrioHighRdy;
    LDR     R1, =OSPrioHighRdy
    LDRB    R2, [R1]
    STRB    R2, [R0]
 
    LDR     R0, =OSTCBCur                                       ; OSTCBCur  = OSTCBHighRdy;
    LDR     R1, =OSTCBHighRdy
    LDR     R2, [R1]
    STR     R2, [R0]
 
    LDR     R0, [R2]                                            ; R0 is new process SP; SP = OSTCBHighRdy->OSTCBStkPtr;
    LDM     R0, {R4-R11}                                        ; Restore r4-11 from new process stack
    ADDS    R0, R0, #0x20
    MSR     PSP, R0                                             ; Load PSP with new process SP
    ORR     LR, LR, #0x04                                       ; Ensure exception return uses process stack
    CPSIE   I
    BX      LR                                                  ; Exception return will restore remaining context
 
    END

zzhere2007

有些东西被c语言隐藏了，看汇编代码，可以看出来。比如。函数调用的时候，也是要存堆栈的，但是c没有表现

cjqhyy

会不会是产生中断时 硬件自动入栈呢？我看书上写的有这种CPU。不过还没做过移植，不懂~~

zzhere2007

呵呵，入栈只是在作函数调用的时候产生，也包括中断。这个操作在c语言的程序里面，一般都不会体现出来，而是编译器在变异的时候自动产生这个操作。所以用c语言，都会加上队列。但是用汇编，可以用堆栈也可以不用

cjqhyy

哦 ，学习了。
你说的  “所以用c语言，都会加上队列”  这个“队列”是什么意思啊？

zzhere2007

不好意思，说错了，是堆栈，呵呵

juntianya

首先，寄存器的值确实是被保存到了任务堆栈中。其次，这部分汇编代码中其实就有将寄存器值保存到任务堆栈的代码，你 把 LDR     R1, =OSTCBCur                                       ;
                                                   LDR     R1, [R1]
                                                  STR     R0, [R1]   这三句看懂了就明白了。