5881|4

13

帖子

0

TA的资源

一粒金砂(中级)

楼主
 

红外(51) [复制链接]

;=================================================
; 红外遥控接收     
;=================================================
;   中山单片机学习网    智佳科技   逸风
;=================================================
ORG 0000H

MAIN:
    JNB    P2.2,IR        ;遥控扫描
    LJMP   MAIN           ;在正常无遥控信号时,一体化红外接收头输出是高电平,程序一直在循环。

;=================================================
;=================================================
;   解码程序
IR:
    ;以下对遥控信号的9000微秒的初始低电平信号的识别,波形见图5。
    MOV    R6,#10
IR_SB:
    ACALL DELAY882        ;调用882微秒延时子程序
    JB     P2.2,IR_ERROR  ;延时882微秒后判断P2.2脚是否出现高电平如果有就退出解码程序
    DJNZ   R6,IR_SB       ;重复10次,目的是检测在8820微秒内如果出现高电平就退出解码程序

    ;识别连发码,和跳过4.5ma的高电平。
    JNB     P2.2, $       ;等待高电平避开9毫秒低电平引导脉冲
    ACALL  DELAY2400
    JNB     P2.2,IR_Rp    ;这里为低电平,认为是连发码信号,见图6。
    ACALL  DELAY2400      ;延时4.74毫秒避开4.5毫秒的结果码

    ;以下32数据码的读取 ,0和1的识别 请看图2
    MOV     R1,#1AH        ;设定1AH为起始RAM区
    MOV     R2,#4
IR_4BYTE:
    MOV     R3,#8
IR_8BIT:   
    JNB     P2.2,$         ;等待地址码第一位的高电平信号
    LCALL  DELAY882    :o  为什么延时是882MS????
    MOV    C,P2.2          ;将P2.2引脚此时的电平状态0或1存入C中
    JNC     IR_8BIT_0      ;如果为0就跳转到IR_8BIT_0
    LCALL  DELAY1000
IR_8BIT_0:
    MOV    A,@R1           ;将R1中地址的给A
    RRC    A               ;将C中的值0或1移入A中的最低位
    MOV    @R1,A           ;将A中的数暂时存放在R1中
    DJNZ   R3,IR_8BIT      ;接收地址码的高8位
    INC    R1              ;对R1中的值加1,换下一个RAM
    DJNZ   R2,IR_4BYTE     ;接收完16位地址码和8位数据码和8位数据,
                           ;存放在1AH/1BH/1CH/1DH的RAM中

    ;解码成功
    JMP    IR_GOTO
IR_Rp:
    ;这里为重复码执行处
    ;按住遥控按键时,每过108ms就到这里来
    JMP    IR_GOTO

IR_ERROR:
    ;错语退出
    LJMP   MAIN ;退出解码子程序

;遥控执行部份
IR_GOTO:
    ;这里还要判断1AH和1BH 两个系统码或用户码,用于识别不同的遥控器
    ;MOV   A,1AH
    ;CJNE  A,#xxH,IR_ERROR   ;用户码1不对则退出
    ;MOV   A,1BH
    ;CJNE  A,#xxH,IR_ERROR   ;用户码2不对则退出

    ;判断两个数据码是否相反
    MOV    A,1CH
    CPL    A
    CJNE   A,1DH,IR_ERROR    ;两个数据码不相反则退出

    ;遥控执行部份
    ;MOV   A,1DH             ;判断对应按键
    ;CJNE  A,#xxH,$+6
    ;LJMP  -à跳到对应按键执行处
    ;CJNE  A,#xxH,$+6
    ;LJMP  -à跳到对应按键执行处

    MOV     P1,1DH         ;将按键的键值通过P1口的8个LED显示出来!
    CLR     P2.3          ;蜂鸣器鸣响-嘀嘀嘀-的声音,表示解码成功
    LCALL  DELAY2400
    LCALL  DELAY2400
    LCALL  DELAY2400
    SETB   P2.3          ;蜂鸣器停止

    ;清除遥控值使连按失效
    MOV    1AH,#00H
    MOV    1BH,#00H
    MOV    1CH,#00H
    MOV    1DH,#00H
    LJMP   MAIN

;=================================================
; 延时子程序
;=============================882
DELAY882: ;1.085x ((202x4)+5)=882
    MOV R7,#202
DELAY882_A:
    NOP
    NOP
    DJNZ   R7,DELAY882_A
RET

;=============================1000
DELAY1000: ;1.085x ((229x4)+5)=999.285
    MOV R7,#229
DELAY1000_A:
    NOP
    NOP
    DJNZ   R7,DELAY1000_A
RET
;=============================2400
DELAY2400: ;1.085x ((245x9)+5)=2397.85
    MOV R7,#245
DELAY2400_A:
    NOP
    NOP
    NOP
    NOP
    NOP
   NOP
    NOP
    DJNZ   R7,DELAY2400_A
RET
END







此帖出自51单片机论坛

最新回复

谢谢楼主,我以将它做为资料保存了。  详情 回复 发表于 2008-8-9 23:27
点赞 关注
 

回复
举报

36

帖子

0

TA的资源

五彩晶圆(初级)

沙发
 
有没有C代码的源程序?
此帖出自51单片机论坛
 
 
 

回复

229

帖子

0

TA的资源

纯净的硅(初级)

板凳
 
呵呵 谢谢 很好 这个很有用
此帖出自51单片机论坛
 
 
 

回复

87

帖子

0

TA的资源

一粒金砂(初级)

4
 

thanks

希望对我有用
此帖出自51单片机论坛
 
 
 

回复

27

帖子

0

TA的资源

一粒金砂(初级)

5
 
谢谢楼主,我以将它做为资料保存了。
此帖出自51单片机论坛
 
 
 

回复
您需要登录后才可以回帖 登录 | 注册

随便看看
查找数据手册?

EEWorld Datasheet 技术支持

相关文章 更多>>
关闭
站长推荐上一条 1/10 下一条
艾睿电子& Silicon Labs 有奖直播 | 全新蓝牙信道探测:从技术创新到实际应用
直播时间:3月12日(周三)上午10:00
直播奖励:多功能榨汁机、蓝牙音箱、手机支架

查看 »

 
EEWorld订阅号

 
EEWorld服务号

 
汽车开发圈

About Us 关于我们 客户服务 联系方式 器件索引 网站地图 最新更新 手机版

站点相关: 国产芯 安防电子 汽车电子 手机便携 工业控制 家用电子 医疗电子 测试测量 网络通信 物联网

北京市海淀区中关村大街18号B座15层1530室 电话:(010)82350740 邮编:100190

电子工程世界版权所有 京B2-20211791 京ICP备10001474号-1 电信业务审批[2006]字第258号函 京公网安备 11010802033920号 Copyright © 2005-2025 EEWORLD.com.cn, Inc. All rights reserved
快速回复 返回顶部 返回列表