这个程序的思路我不懂

mxcb2008

这个程序的思路我不懂 [复制链接]

;***双字节二进制无符号数除法***

;入口条件：被除数在R2、R3、R4、R5中，除数在R6、R7中。

;出口信息：OV=0 时，双字节商在R2、R3中，OV=1 时溢出。

;影响资源：PSW、A、B、R1～R7 堆栈需求： ２字节

DIVD:

       CLR       C           ;比较被除数和除数

       MOV      A,R3

       SUBB     A,R7

       MOV      A,R2

       SUBB     A,R6

       JC          D1

       SETB     OV                ;溢出

       RET

D1:MOV      B,#10H          ;计算双字节商

D2:CLR       C                  ;部分商和余数同时左移一位

       MOV      A,R5

       RLC       A

       MOV      R5,A

       MOV      A,R4

       RLC       A

       MOV      R4,A

       MOV      A,R3

       RLC       A

       MOV      R3,A

       XCH      A,R2

       RLC       A

       XCH      A,R2

       MOV      F0,C             ;保存溢出位

       CLR       C

       SUBB     A,R7             ;计算（R2R3－R6R7）

       MOV      R1,A

       MOV      A,R2

       SUBB     A,R6

       ANL       C,/F0            ;结果判断

       JC          D3

       MOV      R2,A             ;够减，存放新的余数

       MOV      A,R1

       MOV      R3,A

       INC       R5                ;商的低位置一

D3:DJNZ     B,D2             ;计算完十六位商（R4R5）

       MOV      A,R4             ;将商移到R2R3中

       MOV      R2,A

       MOV      A,R5

       MOV      R3,A

       CLR       OV                ;设立成功标志

       RET
这个程序的思路我不太明白，希望各位高手多多指教

sure549

除法的思路都是"移位-比较-相减"....这个看起来并没什么不同...

scorpio

顶一下

wangjunaza

比较,如果够相减,就从被除数中减去除数,并且商为+1,如果不够减就不减,商+0,然后移位....除数右移一位,商左移一位.(如果不是除数移位,就是余数向相反方向移位,反正它们相对移位就行....)

wfdx022

用减法来做除法

LZ再想想

强化工业

就是看被除数中有几个除数，不够的化就是余数。
例如8/3   x为商  y为余数
x＝0  y＝0
8－3 ＝ 5 》0   x＋1
y＝5
5－3 ＝2  》 0  x＋1
y＝2
2－3 ＝ －1 《 0

所以商为2 余数为2

mjwqh

学习。。。。。。。。。。。。