uC/OS-II 51单片机移植，汇编部分链接错误

vvsanny

uC/OS-II 51单片机移植，汇编部分链接错误 [复制链接]

本人想移植一个uC/OS-II到51（C8051F040）单片机上，C语言部分编译链接成功，与MCU相关的汇编部分虽然编译成功却无法链接(OS_CPU_A.ASM 文件)。

1. OS_CPU_A.ASM文件如下:

1. 
   
2. $NOMOD51
   
3. EA        BIT        0A8H.7
   
4. SP        DATA        081H
   
5. B        DATA        0F0H
   
6. ACC        DATA        0E0H
   
7. DPH        DATA        083H
   
8. DPL        DATA        082H
   
9. PSW        DATA        0D0H
   
10. TR0        BIT        088H.4
    
11. TH0        DATA        08CH
    
12. TL0        DATA        08AH
    
13. 
    
14. NAME OS_CPU_A    ;模块名      
    
15. ;定义重定位段
    
16. ?PR?OSStartHighRdy?OS_CPU_A    SEGMENT CODE
    
17. ?PR?OSCtxSw?OS_CPU_A           SEGMENT CODE
    
18. ?PR?OSIntCtxSw?OS_CPU_A        SEGMENT CODE
    
19. ?PR?OSTickISR?OS_CPU_A         SEGMENT CODE
    
20. 
    
21.         
    
22. ;声明引用全局变量和外部子程序
    
23.         EXTRN DATA  (?C_XBP)     ;仿真堆栈指针用于重入局部变量保存
    
24. 
    
25.         EXTRN XDATA (OSTCBCur)
    
26.         EXTRN XDATA (OSTCBHighRdy)
    
27.         EXTRN XDATA (OSRunning)
    
28.         EXTRN XDATA (OSPrioCur)
    
29.         EXTRN XDATA (OSPrioHighRdy)
    
30.    
    
31.         EXTRN CODE  (OSTaskSwHook)
    
32.         EXTRN CODE  (OSIntEnter)
    
33.         EXTRN CODE  (OSIntExit)
    
34.         EXTRN CODE  (OSTimeTick)        
    
35.             
    
36. ;对外声明4个不可重入函数
    
37.         PUBLIC OSStartHighRdy
    
38.         PUBLIC OSCtxSw
    
39.         PUBLIC OSIntCtxSw
    
40.         PUBLIC OSTickISR
    
41.         
    
42.         ;PUBLIC SerialISR        
    
43.    
    
44. ;分配堆栈空间。只关心大小，堆栈起点由keil决定，通过标号可以获得keil分配的SP起点。
    
45. ?STACK SEGMENT IDATA
    
46.         RSEG ?STACK
    
47. OSStack:
    
48.         DS 40H
    
49. OSStkStart IDATA OSStack-1
    
50. 
    
51. ;定义压栈出栈宏
    
52. PUSHALL    MACRO
    
53.         PUSH PSW
    
54.         PUSH ACC
    
55.         PUSH B
    
56.         PUSH DPL
    
57.         PUSH DPH
    
58.         MOV  A,R0   ;R0-R7入栈
    
59.         PUSH ACC
    
60.         MOV  A,R1
    
61.         PUSH ACC
    
62.         MOV  A,R2
    
63.         PUSH ACC
    
64.         MOV  A,R3
    
65.         PUSH ACC
    
66.         MOV  A,R4
    
67.         PUSH ACC
    
68.         MOV  A,R5
    
69.         PUSH ACC
    
70.         MOV  A,R6
    
71.         PUSH ACC
    
72.         MOV  A,R7
    
73.         PUSH ACC
    
74.         ;PUSH SP    ;不必保存SP，任务切换时由相应程序调整
    
75.         ENDM
    
76.    
    
77. POPALL    MACRO
    
78.         ;POP  ACC   ;不必保存SP，任务切换时由相应程序调整
    
79.         POP  ACC    ;R0-R7出栈
    
80.         MOV  R7,A
    
81.         POP  ACC
    
82.         MOV  R6,A
    
83.         POP  ACC
    
84.         MOV  R5,A
    
85.         POP  ACC
    
86.         MOV  R4,A
    
87.         POP  ACC
    
88.         MOV  R3,A
    
89.         POP  ACC
    
90.         MOV  R2,A
    
91.         POP  ACC
    
92.         MOV  R1,A
    
93.         POP  ACC
    
94.         MOV  R0,A
    
95.         POP  DPH
    
96.         POP  DPL
    
97.         POP  B
    
98.         POP  ACC
    
99.         POP  PSW
    
100.         ENDM
     
101.    
     
102. ;子程序
     
103. ;-------------------------------------------------------------------------
     
104.         RSEG ?PR?OSStartHighRdy?OS_CPU_A
     
105. OSStartHighRdy:
     
106.         USING 0    ;上电后51自动关中断，此处不必用CLR EA指令，因为到此处还未开中断，本程序退出后，开中断。
     
107.         LCALL OSTaskSwHook
     
108. 
     
109. OSCtxSw_in:
     
110.    
     
111.         ;OSTCBCur ===> DPTR  获得当前TCB指针，详见C51.PDF第178页
     
112.         MOV  R0,#LOW (OSTCBCur) ;获得OSTCBCur指针低地址，指针占3字节。+0类型+1高8位数据+2低8位数据
     
113.         INC  R0
     
114.         MOV  DPH,@R0    ;全局变量OSTCBCur在IDATA中
     
115.         INC  R0
     
116.         MOV  DPL,@R0
     
117.    
     
118.         ;OSTCBCur->OSTCBStkPtr ===> DPTR  获得用户堆栈指针
     
119.         INC  DPTR        ;指针占3字节。+0类型+1高8位数据+2低8位数据
     
120.         MOVX A,@DPTR     ;.OSTCBStkPtr是void指针
     
121.         MOV  R0,A
     
122.         INC  DPTR
     
123.         MOVX A,@DPTR
     
124.         MOV  R1,A
     
125.         MOV  DPH,R0
     
126.         MOV  DPL,R1
     
127.    
     
128.         ;*UserStkPtr ===> R5  用户堆栈起始地址内容(即用户堆栈长度放在此处)  详见文档说明  指针用法详见C51.PDF第178页   
     
129.         MOVX A,@DPTR     ;用户堆栈中是unsigned char类型数据
     
130.         MOV  R5,A        ;R5=用户堆栈长度
     
131.    
     
132.         ;恢复现场堆栈内容
     
133.         MOV  R0,#OSStkStart
     
134.         
     
135. restore_stack:
     
136.    
     
137.         INC  DPTR
     
138.         INC  R0
     
139.         MOVX A,@DPTR
     
140.         MOV  @R0,A
     
141.         DJNZ R5,restore_stack
     
142.    
     
143.         ;恢复堆栈指针SP
     
144.         MOV  SP,R0
     
145.    
     
146.         ;恢复仿真堆栈指针?C_XBP        
     
147.         INC  DPTR
     
148.         MOVX A,@DPTR
     
149.         MOV  ?C_XBP,A    ;?C_XBP 仿真堆栈指针高8位
     
150.         INC  DPTR
     
151.         MOVX A,@DPTR
     
152.         MOV  ?C_XBP+1,A  ;?C_XBP 仿真堆栈指针低8位
     
153.    
     
154.         ;OSRunning=TRUE
     
155.         MOV  R0,#LOW (OSRunning)
     
156.         MOV  @R0,#01
     
157.    
     
158.         POPALL
     
159.         SETB EA    ;开中断
     
160.         RETI
     
161. ;-------------------------------------------------------------------------
     
162.         RSEG ?PR?OSCtxSw?OS_CPU_A
     
163. OSCtxSw:   
     
164.         PUSHALL
     
165. OSIntCtxSw_in:
     
166.    
     
167.         ;获得堆栈长度和起址
     
168.         MOV  A,SP
     
169.         CLR  C
     
170.         SUBB A,#OSStkStart
     
171.         MOV  R5,A     ;获得堆栈长度        
     
172.    
     
173.         ;OSTCBCur ===> DPTR  获得当前TCB指针，详见C51.PDF第178页
     
174.         MOV  R0,#LOW (OSTCBCur) ;获得OSTCBCur指针低地址，指针占3字节。+0类型+1高8位数据+2低8位数据
     
175.         INC  R0
     
176.         MOV  DPH,@R0    ;全局变量OSTCBCur在IDATA中
     
177.         INC  R0
     
178.         MOV  DPL,@R0
     
179.    
     
180.         ;OSTCBCur->OSTCBStkPtr ===> DPTR  获得用户堆栈指针
     
181.         INC  DPTR        ;指针占3字节。+0类型+1高8位数据+2低8位数据
     
182.         MOVX A,@DPTR     ;.OSTCBStkPtr是void指针
     
183.         MOV  R0,A
     
184.         INC  DPTR
     
185.         MOVX A,@DPTR
     
186.         MOV  R1,A
     
187.         MOV  DPH,R0
     
188.         MOV  DPL,R1
     
189.         
     
190.         ;保存堆栈长度
     
191.         MOV  A,R5
     
192.         MOVX @DPTR,A
     
193.    
     
194.         MOV  R0,#OSStkStart  ;获得堆栈起址
     
195. save_stack:
     
196.    
     
197.         INC  DPTR
     
198.         INC  R0
     
199.         MOV  A,@R0
     
200.         MOVX @DPTR,A
     
201.         DJNZ R5,save_stack
     
202.         
     
203.         ;保存仿真堆栈指针?C_XBP
     
204.         INC  DPTR
     
205.         MOV  A,?C_XBP    ;?C_XBP 仿真堆栈指针高8位
     
206.         MOVX @DPTR,A
     
207.         INC  DPTR
     
208.         MOV  A,?C_XBP+1  ;?C_XBP 仿真堆栈指针低8位
     
209.         MOVX @DPTR,A        
     
210.    
     
211.         ;调用用户程序
     
212.         LCALL OSTaskSwHook
     
213.         
     
214.         ;OSTCBCur = OSTCBHighRdy,注意是三个字节
     
215.         MOV  R0,#OSTCBCur
     
216.                 MOV  R1,#OSTCBHighRdy
     
217.                 MOV  A,@R1
     
218.         MOV  @R0,A
     
219.         INC  R0
     
220.                 INC  R1
     
221.                 MOV  A,@R1
     
222.         MOV  @R0,A
     
223.         INC  R0
     
224.                 INC  R1
     
225.                 MOV  A,@R1
     
226.         MOV  @R0,A
     
227.                
     
228.         ;OSPrioCur = OSPrioHighRdy  使用这两个变量主要目的是为了使指针比较变为字节比较，以便节省时间。
     
229.         MOV  R0,#OSPrioCur
     
230.                 MOV  R1,#OSPrioHighRdy
     
231.                 MOV  A,@R1
     
232.         MOV  @R0,A
     
233.         
     
234.         LJMP OSCtxSw_in
     
235. ;-------------------------------------------------------------------------
     
236.         RSEG ?PR?OSIntCtxSw?OS_CPU_A
     
237.         
     
238. OSIntCtxSw:
     
239. 
     
240.         ;调整SP指针去掉在调用OSIntExit(),OSIntCtxSw()过程中压入堆栈的多余内容
     
241.         ;SP=SP-4
     
242. 
     
243.         MOV  A,SP
     
244.         CLR  C
     
245.         SUBB A,#4
     
246.         MOV  SP,A
     
247.         
     
248.         LJMP OSIntCtxSw_in
     
249. ;-------------------------------------------------------------------------
     
250. 
     
251.         CSEG AT 000BH    ;OSTickISR, 声明绝对段地址，即定时器0中断入口地址
     
252.         LJMP OSTickISR   ;使用定时器0
     
253. 
     
254.         RSEG ?PR?OSTickISR?OS_CPU_A
     
255. 
     
256. OSTickISR:        
     
257.         
     
258.         USING 0        
     
259.         PUSHALL
     
260.         
     
261.         CLR  TR0
     
262.         MOV  TH0,#70H    ;定义Tick=50次/秒(即0.02秒/次)
     
263.         MOV  TL0,#00H    ;OS_CPU_C.C  和  OS_TICKS_PER_SEC
     
264.         SETB TR0
     
265.         
     
266.         LCALL OSIntEnter
     
267.         LCALL OSTimeTick
     
268.         LCALL OSIntExit
     
269.         POPALL        
     
270.         RETI
     
271. ;-------------------------------------------------------------------------
     
272.         END
     

复制代码

2. 链接错误提示如下：
*** ERROR L121: IMPROPER FIXUP
    MODULE:  .\OS_CPU_A.obj (OS_CPU_A)
    SEGMENT: ?PR?OSCTXSW?OS_CPU_A
    OFFSET:  0050H
*** ERROR L121: IMPROPER FIXUP
    MODULE:  .\OS_CPU_A.obj (OS_CPU_A)
    SEGMENT: ?PR?OSCTXSW?OS_CPU_A
    OFFSET:  0052H
*** ERROR L121: IMPROPER FIXUP
    MODULE:  .\OS_CPU_A.obj (OS_CPU_A)
    SEGMENT: ?PR?OSCTXSW?OS_CPU_A
    OFFSET:  005EH
*** ERROR L121: IMPROPER FIXUP
    MODULE:  .\OS_CPU_A.obj (OS_CPU_A)
    SEGMENT: ?PR?OSCTXSW?OS_CPU_A
    OFFSET:  0060H

去Google了半天也没找到答案，望高手指点！

shdh6015

好像设置的程序空间太小了

修改一下code rom size的设置

alan_zhang

说明：OS_CPU_A.ASM 是从网上下载的(自己不太会写汇编-_-), 有少许修改。

matin

看不明白...

86814429

引用 1 楼 arnold9009 的回复:
好像设置的程序空间太小了

修改一下code rom size的设置

呵呵，谢谢arnold9009这么快的回复：
我在"Option for target.." -> "Target" ->"Code rom size:" 已经设置为:" Large: 64K ROM "
编译链接提示占用空间如下:
Program Size: data=75.0 xdata=2964 code=21625
code空间不大于22KB(<64K)左右，我想应该不会是code 空间太小。

sunsink

引用 3 楼 lihongfu 的回复:
看不明白...

呵呵，版面有限，只好贴出这么多的代码了。

abing2005

那可能是OSCTXSW函数的位置超过了跳转指令的寻址范围

daymare

Error L121
Improper Fixup
Summary   *** Error L121
    Improper Fixup
    Module: filename (module-name)
    Segment: segment-name
    Offset: address


Description   After evaluation of absolute fix-ups, an address is not accessible. The improper address along with the specific module name, partial segment, and segment address are displayed. The fix-up command is not processed. This error occurs when an instruction tries do make a memory access that is outside the scope of this instruction (for example MOVX @Ri outside of the PDATA page, or ACALL outside of the 2KB code memory block).  

zhfxuyg

KEIL的错误信息帮助....它说是你要访问的目标走出了指令所能达到的范围

2007bobo2008

引用 6 楼 arnold9009 的回复:
那可能是OSCTXSW函数的位置超过了跳转指令的寻址范围

谢谢 arnold9009 的回复：

1.所有的跳转指令都是LJMP和LCALL，所以应该不会是OSCtxSw函数超出范围。
2.错误提示：
    SEGMENT: ?PR?OSCTXSW?OS_CPU_A
    OFFSET:  0050H
的意思应该是在OSCTXSW段内的0050H偏移地址处存在无效的地址访问。

ttplay

引用 7 楼 great_bug 的回复:
Error L121
Improper Fixup
Summary?  *** Error L121
? ? Improper Fixup
? ? Module: filename (module-name)
? ? Segment: segment-name
? ? Offset: address


Description?  After evaluation of absolute fix-ups, an address is not accessible. The improper address along with the specific module name, partial segment, and segment address are displayed. The fix-up command is not processed. This error occurs when an instruction tries do make a memory access that is outside the scope of this instruction (for example MOVX @Ri outside of the PDATA page, or ACALL outside of the 2KB code memory block).

呵呵，这个Great_Bug回复我第三次提问了，在此感谢下！！
问题已

经解决，谢谢大家：
1. 查看OS_CPU_A.LST文件，找到有出错提示的段和偏移地址：  

1. 
   
2. 0000                 206     OSCtxSw:   
   
3. 004F 7800     F      280          MOV  R0,#OSTCBCur
   
4. 0051 7900     F      281          MOV  R1,#OSTCBHighRdy
   
5. 005D 7800     F      295          MOV  R0,#OSPrioCur
   
6. 005F 7900     F      296          MOV  R1,#OSPrioHighRdy
   

复制代码

发现问题集中在OSTCBCur, OSTCBHighRdy, OSPrioCur, OSPrioHighRdy 四个变量上，查找他们的声明，可以发现：

1.   
   
2. EXTRN XDATA (OSTCBCur)
   
3. EXTRN XDATA (OSTCBHighRdy)
   
4. EXTRN XDATA (OSRunning)
   
5. EXTRN XDATA (OSPrioCur)
   
6. EXTRN XDATA (OSPrioHighRdy)
   

复制代码

原来问题是在变量上，(变量都在XDATA区，却用没用MOVX指令)我还一直以为问题出在OSCTXSW函数上，无语！！

2. 修改如下：

1. 
   
2.         ;OSTCBCur = OSTCBHighRdy,注意是三个字节
   
3.                 ; 第一个字节
   
4.                 MOV   DPTR, #OSTCBHighRdy
   
5.                 MOVX  A,@DPTR          
   
6.                 MOV   DPTR, #OSTCBCur
   
7.                 MOVX  @DPTR,A
   
8.                 ; 第二个字节
   
9.                 MOV   DPTR, #OSTCBHighRdy  
   
10.                 INC   DPTR
    
11.                 MOVX  A,@DPTR         
    
12.                 MOV   DPTR, #OSTCBCur
    
13.                 INC   DPTR
    
14.                 MOVX  @DPTR,A
    
15.                 ; 第三个字节
    
16.                 MOV   DPTR, #OSTCBHighRdy
    
17.                 INC   DPTR
    
18.                 INC   DPTR
    
19.                 MOVX  A,@DPTR       
    
20.                 MOV   DPTR, #OSTCBCur
    
21.                 INC   DPTR
    
22.                 INC   DPTR
    
23.                 MOVX  @DPTR,A
    
24. 
    
25.         ;OSPrioCur = OSPrioHighRdy  使用这两个变量主要目的是为了使指针比较变为字节比较，以便节 省时间。
    
26.                 MOV  DPTR,#OSPrioHighRdy
    
27.                 MOVX  A,@DPTR
    
28.                 MOV  DPTR, #OSPrioCur
    
29.                 MOVX  @DPTR,A
    

复制代码

3. 编译链接，再也没有出现错误，GOD, 谢天谢地！

kfchu

引用 8 楼 great_bug 的回复:
KEIL的错误信息帮助....它说是你要访问的目标走出了指令所能达到的范围

呵呵，这是Great_Bug回复我第三次提问了，在此特别感谢下！！

wyhgod

牛B。我也想移个玩玩

freedom2010

  超级关注，疯狂Mark。

narrzze

MArk

li525628

NB  顶一个