我回来了,上点资料

jxb01033016

我回来了,上点资料 [复制链接]

奋斗了一周,终于把问题根源找出来了,先给大家分享哈!

[ 本帖最后由 jxb01033016 于 2009-11-17 14:45 编辑 ]

jxb01033016

                                        客户提供的时序图





                                           实际测得的波形图

jxb01033016

改正后的时序,如下
  

jxb01033016

                                 100摄氏度波形(P1-P2)

jxb01033016

                                             150摄氏度波形

jxb01033016

                                  190摄氏度波形

jxb01033016

流程图(有BUG):(

jxb01033016

; *******************HI-6 PROJECT for IZMID******************************;
;*********author:Andy Jiang *********************************************;
;*********design start date: 2009-11-13***********************************;
;*********design  end  date: 2009-??-?***********************************;
;************************************************************************;
; ***********change record***********************************************;  
  
  
   pcc           EQU       [017H]
   pc            EQU       [016H]
   pbc           EQU       [015H]
   pb            EQU       [014H]
   pac           EQU       [013H]
   pa            EQU       [012H]
   tmrc          EQU       [0eH]
   tmr           EQU       [0dH]
   intc          EQU       [0bH]
   status        EQU       [0aH]
   wdts          EQU       [09H]
   tblh          EQU       [08H]
   tblp          EQU       [07H]
   pcl           EQU       [06H]
   acc           EQU       [05H]
   bp            EQU       [04H]
   mp1           EQU       [03H]
   iar1          EQU       [02H]
   mp0           EQU       [01H]
   iar0          EQU       [00H]
   OUT10         EQU       pc.1
   OUT11         EQU       pc.2
   LED_ON        EQU       CLR pb.7
   LED_OFF       EQU       SET pb.7
   HEAT_ON       EQU       SET pa.7
   HEAT_OFF      EQU       CLR pa.7
   OUT10_H       EQU       SET pc.1
   OUT10_L       EQU       CLR pc.1
   OUT11_H       EQU       SET pc.2
   OUT11_L       EQU       CLR pc.2
   COM1_IN       EQU       SET pbc.3
   COM1_OUT      EQU       CLR pbc.3
   COM2_IN       EQU       SET pbc.2
   COM2_OUT      EQU       CLR pbc.2
   COM1_H        EQU       SET pb.3
   COM1_L        EQU       CLR pb.3
   COM2_H        EQU       SET pb.2
   COM2_L        EQU       CLR pb.2
   key_up        EQU       pa.5
   key_down      EQU       pa.4
   key_main      EQU       pa.6   
   zero_pos      EQU       pb.1
   heat_in       EQU       pc.0
   hz_50         EQU       229
   temp_low      EQU       10h
   STOP_MODE     EQU       0
   WAIT_MODE     EQU       1
   RUN_MODE      EQU       2
   TEST_MODE     EQU       3
   
   temphigh      EQU       0
   tempequal     EQU       1
   ms10over      EQU       2
   ms500equal    EQU       3
   ms500large    EQU       4
   keypress      EQU       5
   hz50          EQU       6
   
   DATA .SECTION  'DATA'
   ms10_counter     db     ?
   work_mode        db     ?
   main_sw          db     ?
   up_sw            db     ?
   down_sw          db     ?
   measure_counter  db     ?
   ms500_counter    db     ?
   temp_counter     db     ?
   updown_counter   db     ?
   temp_set         db     ?
   tp1              db     ?
   tp2              db     ?
   p1p20            db     ?
   p1p21            db     ?
   p1p22            db     ?
   p1p23            db     ?
   p1p24            db     ?
   p1p25            db     ?
   p1p26            db     ?
   p1p27            db     ?
   p1p28            db     ?
   p1p29            db     ?  
   tempture1        db     ?
   tempture2        db     ?
   tempture3        db     ?
   tempture4        db     ?
   tempture5        db     ?
   tempture6        db     ?
   tempture7        db     ?
   tempture8        db     ?
   tempture9        db     ?
   tempture10       db     ?
   meas_counter     db     ?
   averagetemp      db     ?
   frequency        db     ?
   min              db     ?
   sec              db     ?
   flag             db     ?
   i                db     ?
   maxtemp          db     ?
   mintemp          db     ?
   temp2            db     ?
   temp3            db     ?
   count            db     ?
   x0f8             db     ?
   tempset_image    db     ?
   acc_image        db     ?
   status_image     db     ?
   synsignal        db     ?
   temp1            db     ?
  
   
   CODE .SECTION 'CODE'  
   ORG 000H
   jmp main
   ORG 008H
   jmp timer_interrupt
     
   ORG 010H   
   main:        
                   mov a,70H                    ;io port set
                   mov pac,a
                   mov a,02h
                   mov pbc,A
                   mov A,02h
                   mov pcc,a
                   mov a ,80h
                   mov pb,a
                   clr pa
                   clr pc
                   COM1_L
                   COM2_L
                   HEAT_OFF
                   LED_OFF
cleanmemory:      mov a ,49                   ; clean memory
                   mov temp1 ,a
                   mov a ,offset ms10_counter
                   mov mp0,a
  cleanloop:       clr IAR0  
                   inc mp0
                   sdz temp1    ;
                   jmp cleanloop
                   mov a,0f8h
                   mov x0f8,a               
                   mov a,150
                   mov updown_counter,a
                   mov a,30
                   mov min,a
                   mov a ,33h
                   mov p1p20,a
                   mov a ,40h
                   mov a ,offset p1p20
                   mov mp0,a
                   mov a, offset tempture1
                   mov mp1,a
                   mov a ,05h
                   mov tmr,a
                   mov a,93h
                   mov tmrc,a
                   mov a,05h
                   mov intc,a
                   mov a, 10
                   mov temp_counter,a
                   mov a, 30
                   mov min,a
                   mov a,59
                   mov sec,a
                   mov a,50
                   mov ms500_counter,a
   mainloop:     
                   snz  flag.keypress
                   jmp  jj5
        pp1:       sz  key_main  
                   jmp pp2
                   jmp  pp1
        pp2:       sz   key_up             ;wait for key up  release
                   jmp pp3
                   jmp pp2
        pp3:       snz  key_down           ;wait for key down release
                   jmp pp3  
                   clr flag.keypress              
        jj5:       sz work_mode.0
                   jmp   tt1                    
                   sz work_mode.1         ;work_mode justfly
                   jmp  RUN
                   jmp  STOP
         tt1:      sz  work_mode.1  
                   jmp  TEST                  
                   jmp  WAIT     
         STOP:
               
                   mov a, main_sw         ;read sw_main
                   xor a, x0f8
                   snz  status.2      
                   jmp  mainloop          ;no  main key
                   mov a,WAIT_MODE        ;turn  to wait mode
                   mov work_mode,a
                   LED_ON                 ;led on
                   clr ms500_counter      ;clear counter
                   clr main_sw            ;clear flag     
                   set flag.keypress     
                   jmp mainloop
               
               
         WAIT:     ;snz flag.ms10over
                   ;jmp wait
                   ;clr flag.ms10over            
                   mov a ,main_sw
                   xor a ,x0f8
                   snz status.2
                   jmp kk7
                   clr main_sw
                   LED_OFF
                   mov a ,STOP_MODE
                   mov work_mode,a
                   set flag.keypress
                   jmp mainloop
        kk7:      
                   mov a, up_sw
                   xor a ,x0f8
                   snz  status.2
                   jmp mainloop
                   clr temp_set
                   mov a ,RUN_MODE               
                   mov work_mode,a
                   mov a,30
                   mov min,a
                   mov a,59
                   mov sec,a
                   mov a,50
                   mov ms500_counter,a
                   set flag.keypress
                   jmp mainloop         
       RUN:        snz flag.ms10over                 
                   jmp run
                   clr flag.ms10over
                   sz  ms10_counter.0
                   jmp waitp1high
     waitp2high:   snz heat_in
                   jmp waitp2high      
                   jmp getp2
    waitp1high:    snz  heat_in
                   jmp waitp1high                           
       getp1:      mov a,06h
                   mov pcc,a
                   clr pc.0
                   mov a ,tmr              ;high,get counter
                   mov tp1,a                ;out10=L
                   jmp key_press
      getp2:       mov a,06h
                   mov pcc,a
                   clr pc.0
                   mov a,tmr
                   mov tp2,a              ;
                   mov a ,95
                   add a,tp2
                   sub a ,tp1
                   mov iar0,a             ;
                   mov a,10
                   mov i,a
                   clr temp2                  
                   snz flag.hz50
                   jmp  hz50tab
                   mov a ,31              ;60hz
                   mov temp1, a               
  timetotemp:      mov a, temp1           ;p1p2 -> temp  breakponit here
                   mov tblp,a                           
                   tabrdl temp3
                   mov a,iar0
                   sub a,temp3
                   snz status.0
                   jmp   kk13
                   mov a ,temp2
                   mov iar1,a
                   jmp jj6
      kk13:        inc temp1               ;next loop
                   inc temp2               ;next loop
                   sdz i
                   jmp timetotemp
                   mov a,temp2
                   mov iar1,a
                   jmp jj6
     hz50tab:   
                   mov a ,20      
                   mov temp1,a
                   jmp timetotemp   
                     
      jj6:         inc mp0
                   inc mp1
                   sdz  temp_counter       ;temp_counter--         
                   jmp  key_press          ;add kkkkk for test
                   mov a,offset p1p20     ;reset data ponit
                   mov mp0,a   
                   mov a,offset tempture1
                   mov mp1,a   
                   mov a,10
                   mov temp_counter,a      ;reset tempcounter
                   jmp getmaxmin           ;add test for test
                 
  min30timer:      sdz ms500_counter
                   jmp  key_press
                   mov a ,50
                   mov ms500_counter,a      ;recover
                   sdz sec
                   jmp key_press
                   mov a,60                 ;recover sec
                   mov sec,a
                   sdz min  
                   jmp key_press
                   mov a ,30
                   mov min,a  
   gowaitmode:     HEAT_OFF
                   COM1_OUT
                   COM2_OUT
                   COM1_H
                   COM2_H
                   mov a ,WAIT_MODE         ;turn wait mode
                   mov work_mode,a  
                   jmp mainloop
                 
   getmaxmin:      mov a, offset tempture1
                   mov mp1,a
                   mov a,iar1
                   mov maxtemp,a
                   mov mintemp,a
                   mov a ,9
                   mov i,a
                  
   searchmax:      inc mp1
                   mov a,iar1
                   sub a ,maxtemp
                   snz status.0
                   jmp searchmin
                   mov a,iar1
                   mov maxtemp,a
   searchmin:      mov a,iar1
                   sub a ,mintemp
                   sz  status.0
                   jmp  kk21
                   mov a,iar1
                   mov mintemp,a
       kk21:       sdz  i
                   jmp searchmax
getaveragetemp:   mov a ,0
                   mov averagetemp,a               
                   mov a,10
                   mov i,a
                   mov a,offset tempture1
                   mov mp1,a
     kk24:         mov a,iar1
                   addm a,averagetemp
                   sdz i
                   jmp addnext
                   jmp submaxmin
     addnext:      inc mp1
                   jmp kk24
    submaxmin:     mov a,averagetemp
                   sub a ,maxtemp
                   sub a ,mintemp
                   mov averagetemp,a         ;averagetemp=averagetemp*10
                   clr status.0
                   clr temp1
                   rlc averagetemp
                   rlc temp1
                   mov a,averagetemp
                   rlc averagetemp
                   rlc temp1
                   rlc averagetemp
                   rlc temp1
                   addm a,averagetemp
                   mov a,0
                   adcm a,temp1              
                   addm a,averagetemp
                   clr status.0              ;averagetemp=averagetemp/8
                   rrc temp1                  
                   rrc  averagetemp
                   clr status.0
                   rrc temp1
                   rrc  averagetemp
                   clr status.0
                   rrc temp1
                   rrc  averagetemp                  
                   mov a, offset tempture1
                   mov mp1,a
                   jmp comparetemp
                  
                  ; clr status.0               
    key_press:     mov a,main_sw
                   xor a,x0f8
                   sz  status.2
                   jmp jj1                 ;main= H->L
                   mov a,up_sw
                   xor a,x0f8
                   sz  status.2            ;up=  H->L
                   jmp  jj2
                   mov a,down_sw           ;down= H->L
                   xor a,x0f8
                   sz  status.2
                   jmp jj3
                   jmp display_mode
        jj1:       mov a,WAIT_MODE         ;sw_main function
                   mov work_mode,a         ;turn to wait mode
                   LED_ON
                   OUT10_L
                   OUT11_L
                   HEAT_OFF
                  
                   clr main_sw
                   set flag.keypress     
                   jmp  clrlcd        
        jj2:       set flag.keypress       ;sw_up function
                   mov a,temp_set
                   sub a,9
                   sz  status.2            ;temp equal  9 , process
                   jmp  display_mode
                   sz status.0             ;smaller than 9,increase
                   jmp jj3         
                   inc temp_set
                   clr up_sw
                   jmp display_mode       ;goto diaplay
        jj3:       set flag.keypress       ;sw_down function
                   sz  temp_set            ;temp equal 0 ,no process
                   jmp jj4  
                   clr down_sw           
                   jmp  display_mode      ;goto display
       jj4:        dec temp_set            ;not 0, temp decrease
                   jmp display_mode
                                    
    comparetemp:   mov a,temp_set
                   mov tempset_image,a
                   clr status.0            ;temp_set=temp_set*10 ??
                   clr temp1
                   rlc tempset_image
                   rlc temp1
                   mov a,tempset_image
                   rlc tempset_image
                   rlc temp1
                   rlc tempset_image
                   rlc temp1
                   addm a,tempset_image
                   mov a,0
                   adcm a,temp1              
                   addm a,tempset_image                  
                   mov a,tempset_image            ;averagetemp>temp_set+5 ??
                   add a,5
                   mov temp1,a
                   mov a,averagetemp
                   sub a ,temp1
                   snz  status.0
                   jmp  lowtempture
                   set flag.temphigh
                   clr flag.tempequal
                   jmp key_press
   lowtempture:    mov a,averagetemp           ;averagetemp                    add a,5
                   mov temp1,a   
                   mov a,tempset_image
                   sub a, temp1
                   snz status.0
                   jmp equaltempture
                   clr flag.temphigh
                   clr flag.tempequal
                   jmp key_press
   equaltempture:  set flag.tempequal       ;temp_set-5<=averagetemp<=temp+5     
                   clr flag.temphigh  
                   jmp mainloop
   display_mode:   sz flag.tempequal        ; lcd display  
                   jmp lcdflash             ; put in  interrupt
                   call lcd_display
                   jmp mainloop      
      lcdflash:    sz flag.ms500large
                   jmp clrlcd
     disp:         call lcd_display
                   jmp mainloop
                              
      clrlcd:       COM1_OUT
                    COM2_OUT                  
                    mov a,pb
                    and a,0c3h
                    mov pb,a
                    mov a ,pa
                    and a,0f0h
                    mov pa,a
                    jmp mainloop
                          
      TEST:         snz flag.ms10over
                    jmp TEST
                    clr flag.ms10over
                    snz flag.ms500equal      ;500ms delay havn'e yet
                    jmp pp4
                    clr flag.ms500equal      ;equal  to 500ms  
                    inc temp_set                             
                  ;inc temp_set              ;flash 1s display num add 1
                    mov a,temp_set
                    sub a ,10
                    snz status.2             ;equal 10 ?
                    jmp kk28            
      kk26:         clr temp_set             ; 0-9 display over ,turn to   stop mode   
                    mov a ,STOP_MODE
                    mov work_mode,a
                    LED_OFF
                    mov a,pb
                    and a,0c3h
                    mov pb,a
                    mov a ,pa
                    and a,0f0h
                    mov pa,a
                    COM1_OUT
                    COM2_OUT
                    COM1_L
                    COM2_L
                    set flag.keypress
                    jmp mainloop             ;goto loop
      pp4:          snz flag.ms500large      ;larger than 500ms,on display
                    jmp pp5
                    LED_ON
                    call lcd_display
                    jmp kk28
      pp5:          LED_OFF                  ;less than 500ms,off dispaly
                    COM1_OUT
                    COM2_OUT
                    COM1_L
                    COM2_L
                    mov a,pb
                    and a,0c3h
                    mov pb,a
                    mov a ,pa
                    and a,0f0h
                    mov pa,a  
                    jmp mainloop
     KK28:          mov a ,main_sw
                    xor a ,x0f8
                    sz status.2
                    jmp  kk26
                    mov a ,up_sw
                    xor a ,x0f8
                    sz status.2
                    jmp  kk26
                    mov a,down_sw
                    xor a ,x0f8
                    sz status.2
                    jmp kk26
                    call lcd_display
                    jmp mainloop
   lcd_display:     COM1_OUT
                    COM2_OUT
                    mov a, pb   
                    and a, 0c3h
                    mov pb,a
                    sz ms10_counter.0
                    jmp disp_com1
                    jmp disp_com2
                          
   disp_com1:   
                    COM2_IN
                    mov a, temp_set
                    mov tblp,a
                    tabrdl temp1
                    mov a,pb
                    or a,30h  
                    mov pb,a        
                    mov a,temp1
                    and a,0fh
                    mov temp2,a
                    mov a,pa
                    and a,0f0h
                    or a,temp2
                    mov pa,a
                    COM1_OUT
                    COM1_L            
                    ret
                    
                    
disp_com2 :        mov a, temp_set
                    add a ,10
                    mov tblp,a
                    tabrdl temp1                    
                    COM1_IN
                    mov a,temp1                  
                    and a,30h
                    mov temp2,a
                    mov a ,pb
                    or a,temp2   
                    mov pb,a
                    mov a,temp1
                    and a, 0fh
                    mov temp2, a
                    mov a,pa
                    and a,0f0h
                    or a ,temp2
                    mov pa,a
                    COM2_OUT
                    COM2_L
                    ret
                                            
frequency_detect:
                      mov a ,00h            
                      mov intc,a
                      mov tmr,a              ;clear interrupt
                      mov a,94h
                      mov tmrc,a  
                      sz zero_pos            ;low,wait for high
                      jmp kk4
          kk1:        snz zero_pos           ;high?   
                      jmp kk1                ;low ,go circle
                      mov a ,10h             ; start to count
                      mov tmrc,a
         kk2:         sz zero_pos            ;low ?
                      jmp kk2                ;high,go circle
          kk3:        snz zero_pos           ;low?
                      jmp kk3                ;low,wait for high
                      mov a ,tmr             ;high,read tmr
                      sub a ,hz_50
                      sz  status.0           ;less
                      jmp kk5
                      clr flag.hz50
                      mov a ,30h
                      mov tmr,a
                      jmp kk6
          kk5:        set flag.hz50
                      mov a ,06h  
                      mov tmr,a
          kk6:        mov a ,93h
                      mov tmrc,a
                      mov a,05h
                      mov tmrc,a
                      ret                                      
          kk4:        sz zero_pos
                      jmp kk4           
                      jmp kk1
                     
     
     SYNwithzero:     clr intc
                      clr tmrc
                      clr ms10_counter
                      mov a, offset p1p20
                      mov mp0,a
                      mov a ,10
                      mov temp_counter,a
                      mov a,05h        ;??????????????????????????????????????
                      mov tmr,a
                      sz HEAT_IN
                      jmp waitlow
        golow:        sz HEAT_IN
                      jmp gohigh            
                      jmp golow
                     
      gohigh:        mov a, 93h
                     mov intc,a
                      mov a ,05h
                      mov intc,a
                      ret
       waitlow:       snz  HEAT_IN
                      jmp golow
                      jmp  waitlow
                     
                     
  timer_interrupt:  
                                             
                      mov acc_image,a
                      mov a,status
                      mov status_image,a      ;save status                                       
                      inc ms10_counter
                     ; mov a,work_mode
                     ; sub a,02h
                     ; snz status.2
                     ; jmp zz1
                      snz ms10_counter.0
                      jmp zz2
                      mov a ,05h
                      mov pcc,a                     
                      OUT10_H  
                      ;OUT11_L                   ;start p1
                      ;set flag.ms10over
                      sz flag.tempequal
                      jmp zz3
                      HEAT_ON
                      clr flag.tempequal
                      jmp zz1  
        zz3:         
                      snz flag.temphigh
                      jmp zz4
                      HEAT_OFF
                      ;clr flag.tempequal
                      jmp zz1
        zz4:          snz temp_counter.0
                      jmp zz6
                      HEAT_OFF
                      jmp zz1
        zz6:          HEAT_ON
                      ;set flag.tempequal  
                      jmp zz1
        zz2:          mov a,03h
                      mov pcc,a                     
                      OUT11_H          ;p2 start
                      ;OUT10_L
                      HEAT_OFF  
                 
         zz1:         sz ms10_counter.0
                      jmp zz8
                      sz work_mode
                      jmp zz8
                      sz key_up
                      jmp zz8
                      sz key_down
                      jmp zz8
                      sdz updown_counter
                      jmp zz10
                      mov a,TEST_MODE
                      mov work_mode,a
                      mov a ,150
                      mov updown_counter,a
                      mov a ,100
                      mov ms500_counter,a
                      clr temp_set
                      jmp zz15
       zz8:           snz work_mode.1
                      jmp zz15
       zz14:          sdz  ms500_counter
                      jmp  zz15   
                      mov a ,100
                      mov ms500_counter,a
                      set flag.ms500large
                      clr flag.ms500equal      
       zz15:          mov a ,50
                      sub a, ms500_counter
                      sz status.2
                      jmp zz16
                      sz status.0
                      jmp zz17
                      clr flag.ms500equal         ;lager than 500ms
                      set flag.ms500large
                      jmp zz10
       zz16:          set flag.ms500equal         ;equal 500ms
                      jmp zz10
       zz17:         ; clr flag.ms500equal        
                      clr flag.ms500large         ;less than 500ms
       zz10:          clr status.0      
                      ;rlc main_sw
                      rlc main_sw                ;read key
                      clr status.0
                      rlc up_sw
                      clr status.0
                      rlc down_sw
                      snz key_main
                      jmp zz11
                      set main_sw.0
        zz11:         snz key_up
                      jmp zz12
                      set up_sw.0
        zz12:         snz key_down
                      jmp zz13                     
                      set down_sw.0                                                                  
       zz13:          set flag.ms10over
                     
     turnback:       mov a,status_image   ;recover acc,status
                     mov status,a               
                     mov  a, acc_image
                     reti
       cleanlcd:     COM1_OUT
                     COM2_OUT                  
                     mov a,pb
                     and a,0c3h
                     mov pb,a
                     mov a ,pa
                     and a,0f0h
                     mov pa,a
                     jmp turnback
ORG 300h
lcd_com1 :  dc    0eh,08h,0ch,0ch,0ah,06h,06h,0ch,0eh,0eh
lcd_com2 :  dc    3ah,28h,36h,3ch,2ch,3ch,3eh,28h,3eh,3ch
fre_50hz :  dc    139,109,88,72,61,53,47,42,38,35,33
fre_60hz :  dc    89,64,46,33,23,17,11,7,4,2,0
end

lzcqust

这是什么呀？

jxb01033016

负离子吹风机的温度控制器