【Follow me第二季第4期】进阶任务一 MIC幅度用led颜色展示

oxlm_1

【Follow me第二季第4期】进阶任务一 MIC幅度用led颜色展示 [复制链接]

 

预备知识

        能量检测，属于音频里面最简单的算法了吧，其计算逻辑为：

energy = sqrt((a0 * a0 + a1 * a1 + ... + an * an) / (n + 1))

原理分析

        而经过了前面mic录制信号并打印的部分，我们可以通过波形获取以下信息，在arduino nano rp2040 connect里，音频处理精度为16bit，也就是说算上符号位，破音值在32767 和 -32768。

        经过对上面函数的分析，再结合mic信号范围，我们最终算出的能量信息应该在0~32767之间，此时如果需要转化成pwm的0~255之间，那就很简单了，只需要把数据向右偏移7位即可（如果是定点数的话）。

        之后再自定义交互逻辑，实现三颗不同灯珠的亮度调节即可。

软件编码

        基于上面的分析，我采用了浮点数去计算能量（仅仅是为了防止数据溢出而已，其实2040的m0+核并不支持浮点运算），计算完毕后再将浮点数转化成pwm灯的0~255的占空比信息，之后再按照一定逻辑去分别控制红灯和绿灯（之所以不去控蓝灯，是因为没有灯光罩的前提下，三颗灯实在是拍不出效果，两颗灯反而能透过指甲盖看出变化）。

#include <WiFiNINA.h>
#include <PDM.h>

static const char channels = 1;
static const int frequency = 16000;
short sampleBuffer[512];
volatile int samplesRead;

void setup() {
  //pinMode(LEDB, OUTPUT);
  pinMode(LEDR,OUTPUT);
  pinMode(LEDG,OUTPUT);
  analogWrite(LEDR,255);
  analogWrite(LEDG,255);
  Serial.println("Hello DigiKey & EEWorld!");
  Serial.println();
  Serial.begin(9600);
  while (!Serial);
  PDM.onReceive(onPDMdata);
  if (!PDM.begin(channels, frequency)) {
    Serial.println("Failed to start PDM!");
    while (1);
  }
}

void rgbledShow(float level) {
    unsigned short value = level / 128;
    unsigned char r,g,b;
    Serial.print("value : ");
    Serial.print(value);
    Serial.print(" level: ");
    Serial.println(level);
    r = value;
    g = 255 - value;
    analogWrite(LEDR,r);
    analogWrite(LEDG,g);
}

void micHandle() {
  float level = 0;
  if (samplesRead) {
    for (int i = 0; i < samplesRead; i++) {
      level += (sampleBuffer[i] * sampleBuffer[i]);
    }
    level /= samplesRead;
    level = sqrt(level);
    rgbledShow(level);
    samplesRead = 0;
  }
}

void loop() {
    micHandle();
}

void onPDMdata() {
  // Query the number of available bytes
  int bytesAvailable = PDM.available();
  PDM.read(sampleBuffer, bytesAvailable);
  samplesRead = bytesAvailable / 2;
}

总结

        在这里，又一次回顾了音频处理上的通用做法，后续如有需要，可以进一步的做usb mic之类的玩意玩玩，但不确定arduino是否支持这么玩。