求教：关于UCOS-II任务切换的疑惑

zcj20080882

求教：关于UCOS-II任务切换的疑惑 [复制链接]

 在CM3架构下，UCOS-ii的任务切换在OS_CPU_PendSVHandler中断中进行，其中中断服务代码如下：
OS_CPU_PendSVHandler
    CPSID   I                                                   ; Prevent interruption during context switch
    MRS     R0, PSP                                             ; PSP is process stack pointer
    CBZ     R0, OS_CPU_PendSVHandler_nosave                     ; Skip register save the first time
    SUBS    R0, R0, #0x20                                       ; Save remaining regs r4-11 on process stack
    STM     R0, {R4-R11}
    LDR     R1, =OSTCBCur                                       ; OSTCBCur->OSTCBStkPtr = SP;
    LDR     R1, [R1]
    STR     R0, [R1]                                            ; R0 is SP of process being switched out
                                                                ; At this point, entire context of process has been saved
OS_CPU_PendSVHandler_nosave
    PUSH    {R14}                                               ; Save LR exc_return value
    LDR     R0, =OSTaskSwHook                                   ; OSTaskSwHook();
    BLX     R0
    POP     {R14}
    LDR     R0, =OSPrioCur                                      ; OSPrioCur = OSPrioHighRdy;
    LDR     R1, =OSPrioHighRdy
    LDRB    R2, [R1]
    STRB    R2, [R0]
    LDR     R0, =OSTCBCur                                       ; OSTCBCur  = OSTCBHighRdy;
    LDR     R1, =OSTCBHighRdy
    LDR     R2, [R1]
    STR     R2, [R0]
    LDR     R0, [R2]                                            ; R0 is new process SP; SP = OSTCBHighRdy->OSTCBStkPtr;
    LDM     R0, {R4-R11}                                        ; Restore r4-11 from new process stack
    ADDS    R0, R0, #0x20
    MSR     PSP, R0                                             ; Load PSP with new process SP
    ORR     LR, LR, #0x04                                       ; Ensure exception return uses process stack
    CPSIE   I
    BX      LR      

但是，这里没有操作PC寄存器啊，只是加载了待切换任务运行所需的数据，那怎样切换到任务执行代码那里去的？

jorya_txj

最后一行 BX      LR   会跳过去。建议使用raw-os，有问题可以去raw-os论坛提问。

zcj20080882

jorya_txj 发表于 2015-5-15 10:43
最后一行 BX      LR   会跳过去。建议使用raw-os，有问题可以去raw-os论坛提问。

这里的BX LR应该是中断返回啊，应该返回到被中断的指令处，而不是进入新任务的指令啊？难道这其中还有其他什么操作吗？

zcj20080882

jorya_txj 发表于 2015-5-15 10:43
最后一行 BX      LR   会跳过去。建议使用raw-os，有问题可以去raw-os论坛提问。

我现在连UCOS还没搞懂呢，用RAW-OS有难度吧

鬼眼刀道

看这个汇编语句应该是cortex系列的芯片，芯片一般来说都没有直接操作pc的指令，而是通过引发一次软件中断来实现，在进入中断时CPU会自动将PC压栈，退出时自动出栈。在中断服务程序中将堆栈指向SP改变即可。
所以在cortex上移植时要先认真的把芯片的中断特性搞清楚，这部分内容可以参见cortex-M3权威指南，最后学习UCOSII建议看书（比如这个内容如果看了《嵌入式实时操作系统uc/os-II原理及应用》就应该会了解），然后结合一个具体的芯片，直接看代码很难的。

zcj20080882

鬼眼刀道 发表于 2015-5-16 14:34
看这个汇编语句应该是cortex系列的芯片，芯片一般来说都没有直接操作pc的指令，而是通过引发一次软件中断来实现，在进入中断时CPU会自动将PC压栈，退出时自动出栈。在中断服务程序中将堆栈指向SP改变即可。
所以在cortex上移植时要先认真的把芯片的中断特性搞清楚，这部分内容可以参见cortex-M3权威指南，最后学习UCOSII建议看书（比如这个内容如果看了《嵌入式实时操作系统uc/os-II原理及应用》就应该会了解），然后结合一个具体的芯片，直接看代码很难的。

谢谢哈。我回去认真看一下这些资料